Data:
FILE = 
longitudinal_dyadic wide2.csv;

VARIABLE:
NAMES = id dyadid person idp lengthymean index
deps audits cudits sats trusts commits csts cons
micros isms psss vics sods 
ismp microp pssp vicp sodp satp trustp commitp
cstp conp depp auditp cuditp
depsl auditsl cuditsl 
satsl trustsl commitsl cstsl consl
satpl trustpl commitpl 
cstpl conpl deppl auditpl cuditpl
noncis pover29;

Missing = ALL(-999);

UseVariables are 
micros microp cstsl consl
csts cons cstpl conpl cstp conp
deps depsl lengthymean
satsl trustsl commitsl 
satpl trustpl commitpl
satp trustp commitp
sats trusts commits;

cluster= dyadid; !identifies clustering variable

within are micros microp cstsl consl
csts cons cstpl conpl cstp conp
satsl trustsl commitsl 
satpl trustpl commitpl
satp trustp commitp
sats trusts commits;

between =  lengthymean; !relationship length only varies at the couple level
DEFINE:
center lengthymean (grandmean); !grandmean centers relationship lengths

ANALYSIS:
ESTIMATOR = MLR; 
Type = twolevel; !two-level multilevel model 
MODEL:
%WITHIN%
NRIac BY csts cons; !Creates time t actor negative relationship interaction (NRI) latent variable
NRIpc BY cstp conp; !Creates time t current partner NRI latent variable
[NRIac@0 NRIpc@0]; !Mean centers NRI latent variables

NRIalag BY cstsl consl; !Creates time t-1 actor NRI latent variable
NRIplag BY cstpl conpl; !Creates time t-1 partner NRI latent variable
[NRIalag@0 NRIplag@0];

RQac BY sats trusts commits; !Creates time t actor relationship quality (RQ) latent variable
RQPc BY satp trustp commitp; !Creates time t partner RQ latent variable
[RQpc@0 RQac@0];

RQal BY satsl trustsl commitsl; !Creates time t-1 actor RQ latent variable
RQPl BY satpl trustpl commitpl; !Creates time t-1 partner RQ latent variable
[RQpl@0 RQal@0];

RQac with NRIac; !Allows time t actor RQ and NRI to correlate
RQpc with NRIpc; !Allows time t partner RQ and NRI to correlate

deps ON depsl !depression (dep) at time t-1 prediting dep at time t; controls for dep at the previous timepoint.
micros !Actor effect of microaggressions (time t-1) on dep (time t).
microp !Partner effect of microaggressions (time t-1) on dep (time t).
NRIac (Bac) !Actor effect of NRI (time t) on dep (time t).
NRIpc (Bpc) !Partner effect of NRI (time t) on dep (time t).
RQac (bacr) !Actor effect of RQ (time t) on dep (time t).
RQpc (bpcr) !Partner effect of NRI (time t) on dep (time t).
;
NRIac  ON micros (Aac) !Actor effect of microaggressions (time t-1) on NRI (time t)
microp (Apc) !Partner effect of microaggressions (time t-1) on NRI (time t)
;

RQac ON micros (aacr) !Actor effect of microaggressions (time t-1) on RQ (time t)
microp (apcr) !Partner effect of microaggressions (time t-1) on RQ (time t)
;

!Time t-1 latent variables predicting their parallel time t latent variable. This controls for latent variable at prior timepoint.
NRIac on NRIalag; 
NRIpc on NRIplag;
RQac on RQal;
RQpc on RQpl;

%BETWEEN%
deps on lengthymean; !Controlling for relationship length's effect on average dep score
depsl;

MODEL CONSTRAINTS:
new(caa cap cpa cpp);

caa = Aac*Bac; !Calculating indirect effect coefficient for actor actor effect (actor effect of microaggressions on NRI; actor effect of NRI on dep)
cap = Aac*Bpc; !Calculating indirect effect coefficient for actor partner effect (actor effect of microaggressions on NRI; partner effect of NRI on dep)
cpa = Apc*Bac; !Calculating indirect effect coefficient for partner actor effect (partner effect of microaggressions on NRI; actor effect of NRI on dep)
cpp = Apc*Bpc; !Calculating indirect effect coefficient for partner partner effect (parnter effect of microaggressions on NRI; partner effect of NRI on dep)


OUTPUT: STAND SAMPstat tech1 tech3;